home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / The World of Computer Software.iso / cmsrc392.zip / SYMBOL.MF < prev    next >
Text File  |  1992-03-30  |  44KB  |  1,042 lines
  1. % This file defines the symbols of a \TeX\ math symbol font.
  2. % Character codes \0000--\0100 and \0133--\0177 are generated.
  3.  
  4. % (Improvements to the author's original characters were worked out in 1982
  5. % by Ronald F. Whitney and other members of
  6. % the American Mathematical Society.)
  7.  
  8. % Italic corrections have not been computed for most of these characters,
  9. % since they are generally not slanted.
  10.  
  11. minus=oct"000"; cdot=oct"001"; diamond=oct"005";
  12. plus_minus=oct"006"; o_plus=oct"010"; o_times=oct"012";
  13. eqv=oct"021"; leq=oct"024"; geq=oct"025";
  14. subset=oct"032"; superset=oct"033";
  15. left_arrow=oct"040"; right_arrow=oct"041";
  16. up_arrow=oct"042"; down_arrow=oct"043"; double_arrow=oct"044";
  17. infty=oct"061"; elt=oct"062";
  18. for_all=oct"070"; there_exists=oct"071"; false_that=oct"072";
  19. cup=oct"133"; cap=oct"134"; meet=oct"136"; join=oct"137";
  20. left_brace=oct"146"; right_brace=oct"147"; vertical=oct"152";
  21. backslash=oct"156"; integral=oct"163";
  22.  
  23. input sym;  % symbols common to other fonts
  24.  
  25. cmchar "Times operator";
  26. beginarithchar(oct"002"); pickup rule.nib;
  27. x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
  28. x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
  29. draw z1--z2; draw z3--z4;  % diagonals
  30. labels(1,2,3,4); endchar;
  31.  
  32. cmchar "Asterisk at the axis";
  33. beginchar(oct"003",9u#,v_center(x_height#));
  34. adjust_fit(0,0);
  35. numeric ast_flare; ast_flare=hround .7[thin_join,stem];
  36. x0=.5w; y0=h-.5x_height;
  37. for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
  38.  numeric theta; theta=angle(z[d]-z0);
  39.  fill z0+.5(0,-thin_join)rotated theta
  40.   ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
  41.   ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
  42.   ---z0+.5(0,thin_join)rotated theta--cycle; endfor  % diagonal at angle |d|
  43. labels(0,[-150],[-90],[-30],30,90,150); endchar;
  44.  
  45. cmchar "Elementary division operator";
  46. beginarithchar(oct"004"); pickup rule.nib;
  47. x3-.5dot_size=hround(.5w-.5dot_size); center_on(x3);
  48. y3+.5dot_size=vround(math_axis+math_spread[.5x_height,.6x_height]+.5dot_size);
  49. lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
  50. draw z1--z2;  % bar
  51. pos3(dot_size,0); pos4(dot_size,90); z3=z4;
  52. pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
  53. dot(3,4); dot(5,6);  % dots
  54. penlabels(1,2,3,4,5,6); endchar;
  55.  
  56. cmchar "Minus-or-plus sign";
  57. beginarithchar(oct"007"); pickup rule.nib;
  58. numeric shiftup; shiftup=-vround 1.5u;
  59. x1=x2=.5w; lft x3=lft x5=hround u-eps; x4=x6=w-x3;
  60. .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y1;
  61. draw z1--z2;  % stem
  62. draw z3--z4;  % plus bar
  63. draw z5--z6;  % minus bar
  64. labels(1,2,3,4,5,6); endchar;
  65.  
  66. cmchar "Circle-minus operator";
  67. beginarithchar(oct"011"); pickup light_rule.nib; autorounded;
  68. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  69. circle_points; draw_circle;  % circle
  70. draw z2--z6;  % bar
  71. labels(1,2,3,4,5,6,7,8); endchar;
  72.  
  73. cmchar "Circle-divide operator";
  74. beginarithchar(oct"013"); pickup light_rule.nib; autorounded;
  75. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  76. circle_points; draw_circle;  % circle
  77. draw z1--z5;  % diagonal
  78. labels(1,2,3,4,5,6,7,8); endchar;
  79.  
  80. cmchar "Circle-dot operator";
  81. beginarithchar(oct"014"); pickup light_rule.nib; autorounded;
  82. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  83. circle_points; draw_circle;  % circle
  84. fill fullcircle scaled(1.3dot_size+eps) shifted(.5[z4,z8]);  % dot
  85. labels(1,2,3,4,5,6,7,8); endchar;
  86.  
  87. cmchar "Circle for copyright, etc.";
  88. beginchar(oct"015",18u#,asc_height#,desc_depth#); autorounded;
  89. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  90. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  91. circle_points; draw_circle;  % circle
  92. labels(1,2,3,4,5,6,7,8); endchar;
  93.  
  94. cmchar "Circle operator";
  95. beginchar(oct"016",9u#,v_center(7u#));
  96. adjust_fit(0,0); pickup rule.nib; autorounded;
  97. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
  98. circle_points; draw_circle;  % circle
  99. labels(1,2,3,4,5,6,7,8); endchar;
  100.  
  101. cmchar "Bullet";
  102. beginchar(oct"017",9u#,v_center(7u#));
  103. adjust_fit(0,0); pickup rule.nib; autorounded;
  104. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
  105. filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
  106.   ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;  % circle and interior
  107. labels(1,2,3,4,5,6,7,8); endchar;
  108.  
  109. cmchar "Hardy's asymptotic equivalence sign";
  110. compute_spread(.45x_height#,.55x_height#);
  111. beginchar(oct"020",14u#,v_center(2spread#+rule_thickness#));
  112. adjust_fit(0,0); pickup rule.nib; autorounded;
  113. lft x1=hround u-eps; x3=x1; x2=x4=w-x1; x5=x6=.5w;
  114. y1=y2=good.y h; y3=y4; .5[y1,y3]=.5[y5,y6]=math_axis;
  115. y5=good.y .3[y1,y3];
  116. draw z1{x5-x1,2(y5-y1)}...z5{right}...z2{x2-x5,2(y2-y5)};  % upper bar
  117. draw z3{x6-x3,2(y6-y3)}...z6{right}...z4{x4-x6,2(y4-y6)};  % lower bar
  118. labels(1,2,3,4); endchar;
  119.  
  120. cmchar "Subset or equal to sign";
  121. compute_spread(.45x_height#,.55x_height#);
  122. spread#':=spread#; spread':=spread; % the spread of `$=$'
  123. compute_spread(5/4x_height#,3/2x_height#);
  124. beginchar(oct"022",14u#,v_center(spread#'+spread#+rule_thickness#));
  125. adjust_fit(0,0); pickup rule.nib; autorounded;
  126. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  127. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  128. x4=x5=.5w; y4=y1; y5=y3;
  129. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  130. x8=x1; lft x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  131. labels(1,2,3,4,5,8,9); endchar;
  132.  
  133. cmchar "Superset or equal to sign";
  134. compute_spread(.45x_height#,.55x_height#);
  135. spread#':=spread#; spread':=spread; % the spread of `$=$'
  136. compute_spread(5/4x_height#,3/2x_height#);
  137. beginchar(oct"023",14u#,v_center(spread#'+spread#+rule_thickness#));
  138. adjust_fit(0,0); pickup rule.nib; autorounded;
  139. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  140. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  141. x4=x5=.5w; y4=y1; y5=y3;
  142. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  143. x8=x1; rt x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  144. labels(1,2,3,4,5,8,9); endchar;
  145.  
  146. cmchar "Precedes or equals sign";
  147. compute_spread(.45x_height#,.55x_height#);
  148. spread#':=spread#; spread':=spread; % the spread of `$=$'
  149. compute_spread(5/4x_height#,3/2x_height#);
  150. beginchar(oct"026",14u#,v_center(spread#'+spread#+rule_thickness#));
  151. adjust_fit(0,0); pickup rule.nib; autorounded;
  152. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  153. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  154. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  155. draw z3{-u,spread}...{left}z2;  % lower diagonal
  156. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  157. labels(1,2,3,8,9); endchar;
  158.  
  159. cmchar "Follows or equals sign";
  160. compute_spread(.45x_height#,.55x_height#);
  161. spread#':=spread#; spread':=spread; % the spread of `$=$'
  162. compute_spread(5/4x_height#,3/2x_height#);
  163. beginchar(oct"027",14u#,v_center(spread#'+spread#+rule_thickness#));
  164. adjust_fit(0,0); pickup rule.nib; autorounded;
  165. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  166. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  167. draw z1{u,-spread}...{right}z2;  % upper diagonal
  168. draw z3{u,spread}...{right}z2;  % lower diagonal
  169. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  170. labels(1,2,3,8,9); endchar;
  171.  
  172. cmchar "Similarity sign";
  173. compute_spread(.45x_height#,.55x_height#);
  174. beginchar(oct"030",14u#,v_center(spread#+rule_thickness#));
  175. adjust_fit(0,0);
  176. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  177. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  178. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  179. bot y1=bot y3=-d; top y2=top y4=h;
  180. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  181. labels(1,2,3,4); endchar;
  182.  
  183. cmchar "Approximate equality sign";
  184. compute_spread(.45x_height#,.55x_height#);
  185. spread#':=spread#; spread':=spread; % the spread of `$=$'
  186. compute_spread(.54x_height#,.66x_height#);
  187. beginchar(oct"031",14u#,v_center(spread#'+spread#+rule_thickness#));
  188. adjust_fit(0,0);
  189. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  190. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  191. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  192. y1=y3; top y2=top y4=h; top y2-bot y1=spread';
  193. draw z1{up}...z2{right}..{right}z3...{up}z4;  % upper stroke
  194. z1-z5=z2-z6=z3-z7=z4-z8=(0,spread);
  195. draw z5{up}...z6{right}..{right}z7...{up}z8;  % lower stroke
  196. labels(1,2,3,4,5,6,7,8); endchar;
  197.  
  198. cmchar "Much less sign";
  199. compute_spread(5/4x_height#,3/2x_height#);
  200. beginchar(oct"034",18u#,v_center(spread#+rule_thickness#));
  201. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  202. lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
  203. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  204. draw z1--z2--z3;  % left diagonals
  205. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  206. draw z4--z5--z6;  % right diagonals
  207. labels(1,2,3,4,5,6); endchar;
  208.  
  209. cmchar "Much greater sign";
  210. compute_spread(5/4x_height#,3/2x_height#);
  211. beginchar(oct"035",18u#,v_center(spread#+rule_thickness#));
  212. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  213. lft x1=hround u-epsilon; x2=hround 12.5u-x1; x3=x1;
  214. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  215. draw z1--z2--z3;  % left diagonals
  216. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  217. draw z4--z5--z6;  % right diagonals
  218. labels(1,2,3,4,5,6); endchar;
  219.  
  220. cmchar "Precedes sign";
  221. compute_spread(5/4x_height#,3/2x_height#);
  222. beginchar(oct"036",14u#,v_center(spread#+rule_thickness#));
  223. adjust_fit(0,0); pickup rule.nib; autorounded;
  224. lft x2=hround 1.5u-epsilon; x1=x3=w-x2;
  225. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  226. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  227. draw z3{-u,spread}...{left}z2;  % lower diagonal
  228. labels(1,2,3); endchar;
  229.  
  230. cmchar "Follows sign";
  231. compute_spread(5/4x_height#,3/2x_height#);
  232. beginchar(oct"037",14u#,v_center(spread#+rule_thickness#));
  233. adjust_fit(0,0); pickup rule.nib; autorounded;
  234. lft x1=hround 1.5u-epsilon; x2=w-x1; x3=x1;
  235. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  236. draw z1{u,-spread}...{right}z2;  % upper diagonal
  237. draw z3{u,spread}...{right}z2;  % lower diagonal
  238. labels(1,2,3); endchar;
  239.  
  240. cmchar "Northeast arrow";
  241. beginchar(oct"045",18u#,asc_height#,asc_depth#);
  242. adjust_fit(0,0); pickup crisp.nib;
  243. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  244. y1-.5rule_thickness=-d; top y0=h;
  245. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  246. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  247. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  248. pos3(rule_thickness,theta); pos4(rule_thickness,theta);
  249. z3-z0=(-4u,.36asc_height) rotated theta;
  250. z4-z0=(-4u,-.36asc_height) rotated theta;
  251. pos5(rule_thickness,-90); z5l=z0; pos6(rule_thickness,-180); z6l=z0;
  252. z9=.2[.5[z3,z4],z0];
  253. numeric t; path p; p=z4l{z9-z4}..z6r;
  254. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  255. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  256.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  257.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  258. penlabels(0,1,2,3,4,5,6,9); endchar;
  259.  
  260. cmchar "Southeast arrow";
  261. beginchar(oct"046",18u#,asc_height#,asc_depth#);
  262. adjust_fit(0,0); pickup crisp.nib;
  263. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  264. y1+.5rule_thickness=h; bot y0=-d;
  265. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  266. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  267. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  268. pos3(rule_thickness,theta); pos4(rule_thickness,theta);
  269. z3-z0=(-4u,.36asc_height) rotated theta;
  270. z4-z0=(-4u,-.36asc_height) rotated theta;
  271. pos5(rule_thickness,180); z5l=z0; pos6(rule_thickness,90); z6l=z0;
  272. z9=.2[.5[z3,z4],z0];
  273. numeric t; path p; p=z4l{z9-z4}..z6r;
  274. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  275. filldraw z0..{z4-z9}z4r
  276.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  277.  --z2l---z1l..z1r---z2r
  278.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  279.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  280. penlabels(0,1,2,3,4,5,6,9); endchar;
  281.  
  282. cmchar "Similar or equal sign";
  283. compute_spread(.45x_height#,.55x_height#);
  284. beginchar(oct"047",14u#,v_center(2spread#+rule_thickness#));
  285. adjust_fit(0,0);
  286. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  287. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  288. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  289. bot y1=bot y3=floor math_axis; top y2=top y4=h;
  290. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  291. pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
  292. draw z5--z6;  % bar
  293. labels(1,2,3,4,5,6); endchar;
  294.  
  295. cmchar "Double leftward arrow";
  296. compute_spread(.45x_height#,.55x_height#);
  297. beginchar(oct"050",18u#,v_center(spread#+rule_thickness#));
  298. adjust_fit(0,0); pickup rule.nib;
  299. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  300. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  301. draw z1--z7; draw z2--z8;  % bars
  302. pickup crisp.nib; lft x0=hround u-eps; y0=good.y math_axis;
  303. pos3(rule_thickness,0); pos4(rule_thickness,0);
  304. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
  305. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  306. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  307. z9=.381966[.5[z3,z4],z0];
  308. erase filldraw z0..{z3-z9}z3--(0,y3)
  309.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  310. numeric t; path p; p=z4r{z9-z4}..z6r;
  311. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  312. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  313.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  314. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  315.  
  316. cmchar "Double rightward arrow";
  317. compute_spread(.45x_height#,.55x_height#);
  318. beginchar(oct"051",18u#,v_center(spread#+rule_thickness#));
  319. adjust_fit(0,0); pickup rule.nib;
  320. lft x1=hround u-eps; x2=x1; x7=x8=w-x1;
  321. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  322. draw z1--z7; draw z2--z8;  % bars
  323. pickup crisp.nib; rt x0=hround(w-u)+eps; y0=good.y math_axis;
  324. pos3(rule_thickness,0); pos4(rule_thickness,0);
  325. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
  326. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  327. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  328. z9=.381966[.5[z3,z4],z0];
  329. erase filldraw z0..{z3-z9}z3--(w,y3)
  330.  --(w,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  331. numeric t; path p; p=z4l{z9-z4}..z6r;
  332. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  333. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  334.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  335. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  336.  
  337. cmchar "Double upward arrow";
  338. beginchar(oct"052",11u#,asc_height#,asc_depth#);
  339. adjust_fit(0,0); pickup rule.nib;
  340. compute_spread(.45x_height#,.55x_height#);
  341. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  342. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  343. draw z1--z7; draw z2--z8;  % bars
  344. pickup crisp.nib; top y0=h+eps; x0=good.x .5w;
  345. pos3(rule_thickness,90); pos4(rule_thickness,90);
  346. x2-x3=x4-x1=3u+eps; y3=y4=y0-.48asc_height-eps;
  347. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  348. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  349. z9=.381966[.5[z3,z4],z0];
  350. erase filldraw z0..{z3-z9}z3--(x3,h)
  351.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess
  352. numeric t; path p; p=z4l{z9-z4}..z6r;
  353. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  354. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  355.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  356. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  357.  
  358. cmchar "Double downward arrow";
  359. beginchar(oct"053",11u#,asc_height#,asc_depth#);
  360. adjust_fit(0,0); pickup rule.nib;
  361. compute_spread(.45x_height#,.55x_height#);
  362. top y1=top y2=h+eps; bot y7=-d; y8=y7;
  363. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  364. draw z1--z7; draw z2--z8;  % bars
  365. pickup crisp.nib; bot y0=-d-eps; x0=good.x .5w;
  366. pos3(rule_thickness,90); pos4(rule_thickness,90);
  367. x2-x3=x4-x1=3u+eps; y3=y4=y0+.48asc_height-eps;
  368. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  369. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  370. z9=.381966[.5[z3,z4],z0];
  371. erase filldraw z0..{z3-z9}z3--(x3,-d)
  372.  --(x4,-d)--z4{z9-z4}..z0 & cycle;  % erase excess
  373. numeric t; path p; p=z4r{z9-z4}..z6r;
  374. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  375. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  376.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  377. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  378.  
  379. cmchar "Double left-and-right arrow";
  380. compute_spread(.45x_height#,.55x_height#);
  381. beginchar(oct"054",18u#,v_center(spread#+rule_thickness#));
  382. adjust_fit(if monospace: -u#,-u# else: 0,0 fi); pickup rule.nib;
  383. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  384. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  385. draw z1--z7; draw z2--z8;  % bars
  386. pickup crisp.nib; lft x0=hround u-o; y0=good.y math_axis;
  387. pos3(rule_thickness,0); pos4(rule_thickness,0);
  388. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+5u+eps;
  389. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  390. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  391. z9=.381966[.5[z3,z4],z0];
  392. erase filldraw z0..{z3-z9}z3--(0,y3)
  393.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess at left
  394. numeric t; path p; p=z4r{z9-z4}..z6r;
  395. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  396. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  397.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)
  398.  --z3l{z9-z3}..z0 & cycle;  % left arrowhead
  399. rt x10=hround(w-u)+o; y10=good.y math_axis;
  400. pos13(rule_thickness,0); pos14(rule_thickness,0);
  401. y13=y3; y14=y4; x13=x14=x10-5u-eps;
  402. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  403. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  404. z19=.381966[.5[z13,z14],z10];
  405. erase filldraw z10..{z13-z19}z13--(w,y13)
  406.  --(w,y14)--z14{z19-z14}..z10 & cycle;  % erase excess at right
  407. numeric t; path p; p=z14l{z19-z14}..z16r;
  408. t=xpart(p intersectiontimes((0,y10)--(w,y10)));
  409. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  410.  --subpath (t,0) of\\(z13l{z19-z13}..z15r)
  411.  --z13r{z19-z13}..z10 & cycle; % right arrowhead
  412. penlabels(0,1,2,3,4,5,6,7,8,9,10,13,14,15,16,19); endchar;
  413.  
  414. cmchar "Northwest arrow";
  415. beginchar(oct"055",18u#,asc_height#,asc_depth#);
  416. adjust_fit(0,0); pickup crisp.nib;
  417. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  418. y1-.5rule_thickness=-d; top y0=h;
  419. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  420. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  421. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  422. pos3(rule_thickness,-180+theta); pos4(rule_thickness,-180+theta);
  423. z4-z0=(4u,.36asc_height) rotated theta;
  424. z3-z0=(4u,-.36asc_height) rotated theta;
  425. pos5(rule_thickness,0); z5l=z0; pos6(rule_thickness,-90); z6l=z0;
  426. z9=.2[.5[z3,z4],z0];
  427. numeric t; path p; p=z4l{z9-z4}..z6r;
  428. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  429. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  430.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  431.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  432. penlabels(0,1,2,3,4,5,6,9); endchar;
  433.  
  434. cmchar "Southwest arrow";
  435. beginchar(oct"056",18u#,asc_height#,asc_depth#);
  436. adjust_fit(0,0); pickup crisp.nib;
  437. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  438. y1+.5rule_thickness=h; bot y0=-d;
  439. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  440. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  441. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  442. pos3(rule_thickness,-180+theta); pos4(rule_thickness,-180+theta);
  443. z4-z0=(4u,.36asc_height) rotated theta;
  444. z3-z0=(4u,-.36asc_height) rotated theta;
  445. pos5(rule_thickness,90); z5l=z0; pos6(rule_thickness,0); z6l=z0;
  446. z9=.2[.5[z3,z4],z0];
  447. numeric t; path p; p=z4l{z9-z4}..z6r;
  448. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  449. filldraw z0..{z4-z9}z4r
  450.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  451.  --z2l---z1l..z1r---z2r
  452.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  453.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  454. penlabels(0,1,2,3,4,5,6,9); endchar;
  455.  
  456. cmchar "Proportionality sign";
  457. beginchar(oct"057",16.5u#,x_height#,0);
  458. italcorr x_height#*slant-.5u#;
  459. adjust_fit(0,-2.5u#); pickup fine.nib;
  460. numeric theta,phi; phi=angle(3u,h); theta=angle(5u,-h);
  461. pos1(vair,180); pos2(.5[vair,stem],90+.5theta); pos3(stem,90+theta);
  462. pos4(stem,90+theta); pos5(.5[vair,stem],90+.5theta);
  463. pos6(vair,180); pos7(.2[vair,stem],270+.5phi);
  464. pos8(.3[vair,stem],270+phi); pos9(.2[vair,stem],270+.5phi);
  465. lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
  466. if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
  467. y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
  468. x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
  469. y3-y4=h/3; z3-z4=whatever*dir theta;
  470. filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}...z6e{up}
  471.  ...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % `infinity' bowls
  472. erase fill (w-3.5u,h+o)--(w,h+o)
  473.  --(w,-o)--(w-3.5u,-o)--cycle; % erase excess
  474. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  475.  
  476. cmchar "Prime symbol (intended as superscript only)";
  477. beginchar(oct"060",3u#+max(1.75u#,curve#+2(curve#-stem#)),
  478.  .8asc_height#,0);
  479. adjust_fit(0,0); pickup fine.nib;
  480. numeric light_stem,heavy_stem;
  481. light_stem=hround .5[vair,stem]; heavy_stem=hround(bold+2dw);
  482. x1+.5heavy_stem=hround(w-.25u); y1+.5heavy_stem=h;
  483. x2-.5light_stem=hround .5u; y2=1/12asc_height;
  484. numeric theta; theta=angle(z1-z2)-90;
  485. pos1(heavy_stem,theta); pos2(light_stem,theta);
  486. filldraw circ_stroke z1e--z2e;  % diagonal
  487. penlabels(1,2); endchar;
  488.  
  489. cmchar "Ownership sign";
  490. compute_spread(5/4x_height#,3/2x_height#);
  491. beginchar(oct"063",12u#,v_center(spread#+rule_thickness#));
  492. adjust_fit(0,0); pickup rule.nib; autorounded;
  493. lft x1=hround 1.5u-eps; x1=x3=x6=w-x2;
  494. y1-y3=spread; y2=y6=.5[y1,y3]=math_axis;
  495. x4=x5=.5w-u; y4=y1; y5=y3;
  496. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  497. draw z2--z6;  % middle bar
  498. labels(1,2,3,4,5,6); endchar;
  499.  
  500. cmchar "Large triangle";
  501. beginchar(oct"064",16u#,asc_height#,desc_depth#);
  502. adjust_fit(0,0); pickup rule.nib;
  503. bot y1=0; y2=y1; top y3=h+o;
  504. .5[x1,x2]=x3=good.x .5w; center_on(x3); lft x1=hround(.5w-u*sqrt48);
  505. draw z1--z2--z3--cycle;  % stroke
  506. labels(1,2,3); endchar;
  507.  
  508. cmchar "Large inverted triangle";
  509. beginchar(oct"065",16u#,asc_height#,desc_depth#);
  510. adjust_fit(0,0); pickup rule.nib;
  511. top y1=h-d; y2=y1; bot y3=-d-o;
  512. .5[x1,x2]=x3=good.x .5w; center_on(x3); lft x1=hround(.5w-u*sqrt48);
  513. draw z1--z2--z3--cycle;  % stroke
  514. labels(1,2,3); endchar;
  515.  
  516. cmchar "Zero-width slash to negate a relation";
  517. beginchar(oct"066",14u#,asc_height#,asc_depth#);
  518. adjust_fit(0,0); pickup rule.nib;
  519. rt x5=hround(w-2.5u)-eps; lft x6=hround 2.5u+eps;
  520. top y5=h+o; .5[y5,y6]=math_axis;
  521. draw z5--z6;  % diagonal
  522. labels(5,6); zero_width; endchar;
  523.  
  524. cmchar "Maps-to relation";
  525. compute_spread(.45x_height#,.55x_height#);
  526. beginchar(oct"067",14u#,v_center(spread#+rule_thickness#));
  527. % this character should be followed immediately by minus or rightarrow
  528. adjust_fit(0,0); pickup rule.nib;
  529. lft x1=hround u; x2=x1+.5u; x3=x4=x1;
  530. y1=y2=math_axis; y1-y3=y4-y1=.24asc_height+eps;
  531. draw z3--z4;  % stem
  532. draw z1--z2;  % bar stub
  533. labels(1,2,3,4); zero_width; endchar;
  534.  
  535. cmchar "Empty set symbol";
  536. beginchar(oct"073",9u#,body_height#,body_height#-asc_height#);
  537. adjust_fit(0,0);
  538. penpos1(vair,90); penpos3(vair,-90); penpos2(stem,180); penpos4(stem,0);
  539. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  540. x2r=hround max(.7u,1.45u-.5stem);
  541. x4r=w-x2r; x1=x3=.5w; y1r=asc_height+o; y3r=-o;
  542. y2=y4=.5asc_height-vair_corr; y2l:=y4l:=.52asc_height;
  543. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  544.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  545. pickup rule.nib; lft x6=hround 2u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
  546. draw z5--z6;  % diagonal
  547. penlabels(1,2,3,4,5,6); endchar;
  548.  
  549. cmchar "Uppercase Fraktur R";
  550. beginchar(oct"074",13u#,asc_height#,0);
  551. adjust_fit(0,0); pickup fine.nib;
  552. pos1(hair,0); pos2(vair,90); pos3(1/6[hair,stem],190);
  553. pos4(1/4[hair,stem],210); pos5(1/8[hair,stem],190);
  554. pos6(vair,90); pos7(cap_stem,0); pos8(cap_stem,0);
  555. pos9(vair,-90); pos10(hair,-135); pos11(hair,-135);
  556. pos12(vair,135); pos13(vair,135);
  557. lft x1l=lft x5r=hround u; x2=.4[x1,x3]; rt x3l=hround 3.5u; x4=.6[x3,x5];
  558. x6=3u; lft x7=hround(6u-.5cap_stem); x8=x7;
  559. x9=3.5u; x10=5/3u; x11=4/3u; x12=u; x13=2u;
  560. y1=.47h; bot y2l=vround.35h; y3=1/3[y2,y6]; y5=3/4[y2,y6]; y4=.6[y3,y5];
  561. top y6r=h+oo; y7=.64h; y8=.57y7; bot y9r=-o;
  562. y10=1/6y7; y12=1/5y7; y13=1/4y7;
  563. z11-z10=whatever*(z13-z12) rotated 90;
  564. filldraw stroke z1e{down}...z2e{right}...z3e{up}..z4e..z5e{up}
  565.  ...pulled_arc.e(6,7)..pulled_arc.e(8,9)
  566.  ...z10e---z11e;  % flourish and left stem
  567. filldraw stroke z12e--z13e;  % cross
  568. pos20(cap_bar,180); pos21(cap_bar,90);
  569. x20=x7; y20=.75h; rt x21=hround(w-3.5u+.5cap_stem); top y21r=h+o;
  570. filldraw stroke z20e{up}...{right}z21e;  % top of bowl
  571. rt x22r=hround(w-.1u); y22r=good.y .64h;
  572. numeric theta; theta=angle(z21r-z22r);
  573. pos22(cap_stem,theta-90); pos23(cap_bar,theta); z22l=z23l;
  574. path p; p=z20{up}...(z21--(w,y21));
  575. z=p intersectionpoint(z22l--z22l+(h,0) rotated theta);
  576. filldraw z--z21r--z22r--z22l--cycle;  % diagonal of bowl
  577. pos24(cap_bar,90); pos25(cap_bar,90); x24=w-4u; x25=x7;
  578. y24=y25; top y24r=vround(.52h+.5cap_bar);
  579. filldraw stroke z23e{dir(theta+90)}...z24e---z25e;  % bottom of bowl
  580. pos26(cap_stem,0); pos27(cap_stem,0); pos28(cap_stem,0);
  581. x26=x24; x27=x26+.25u; x28l=w-2.5u; y26=y24r; y27=1/3y26; bot y28=-o;
  582. filldraw stroke z26e--z27e...{right}z28e;  % lower diagonal
  583. pos29(cap_bar,0); pos30(cap_bar,-30); z29l=z28l;
  584. x30r=good.x(w-.5u); y30r=good.y .09h;
  585. erase filldraw z29r--z28r--z30r--cycle;  % erase excess
  586. filldraw stroke z29e--z30e;  % serif of lower diagonal
  587. %% \begingroup\thinmuskip=3mu
  588. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,20,21,22,23,24,25,26,27,28,29,30);
  589. %% \endgroup
  590. endchar;
  591.  
  592. cmchar "Uppercase Fraktur I";
  593. beginchar(oct"075",13u#,asc_height#,0);
  594. adjust_fit(0,0); pickup fine.nib;
  595. pos1(vair,270); pos2(cap_hair,180); pos3(vair,90);
  596. pos4(cap_stem,0); pos5(vair,90); pos6(cap_hair,180);
  597. x1=5u; lft x2r=hround u; x3=.5[x2,x4l]; x4r=x5-.75u;
  598. x5=.5[x4l,x6l]; rt x6l=hround(w-.5u);
  599. top y1l=vround.5h; y2=.5[y1,y3]; top y3r=h+oo;
  600. y4=.2[y5,y3]; y6=.3[y5,y3]; bot y5l=ceiling(1/6[x_height,h]);
  601. filldraw stroke z1e{left}...z2e{up}...z3e{right}
  602.  ..z4e..z5e{right}...{up}z6e;  % upper stroke
  603. pos7(vair,90); pos8(cap_stem,0); pos9(cap_stem,0);
  604. lft x7=hround u; z7r=z8l; x9=.5w+u; y8=good.y .25h; bot y9=-oo;
  605. filldraw z8l---z8r..{right}z9r+(0,eps)
  606.  --z9r---z9l..{left}z7l--cycle;  % lower left stroke
  607. pos10(cap_stem,0); pos11(cap_stem,0); pos12(vair,-90); pos13(cap_hair,-180);
  608. x10=w-2.5u; x11r=x12-u; x12=x5; x13=x6;
  609. y10=1/3y12; y11=3/4y12; top y12l=x_height; y13=4/5y12;
  610. filldraw z9l+(0,eps){right}...{up}z10l
  611.  --z10r{down}...z9r---z9l--cycle;  % lower link
  612. filldraw stroke z10e{up}...z11e{up}
  613.  ...z12e{right}...{down}z13e;  % lower right stroke
  614. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
  615.  
  616. cmchar "Lattice top";
  617. beginchar(oct"076",14u#,asc_height#,0);
  618. adjust_fit(0,0); pickup rule.nib;
  619. x1=x2=good.x .5w; center_on(x1); lft x3=hround u; x4=w-x3;
  620. bot y1=0; y2-y1=x4-x3;
  621. if top y2>h: y2:=bot h; fi
  622. y3=y4=y2;
  623. draw z1--z2;  % stem
  624. draw z3--z4;  % bar
  625. labels(1,2,3,4); endchar;
  626.  
  627. cmchar "Perpendicular sign or lattice bottom";
  628. beginchar(oct"077",14u#,asc_height#,0);
  629. adjust_fit(0,0); pickup rule.nib;
  630. x1=x2=good.x .5w; center_on(x1); lft x3=hround u; x4=w-x3;
  631. bot y1=0; y2-y1=x4-x3;
  632. if top y2>h: y2:=bot h; fi
  633. y3=y4=y1;
  634. draw z1--z2;  % stem
  635. draw z3--z4;  % bar
  636. labels(1,2,3,4); endchar;
  637.  
  638. cmchar "Hebrew letter aleph";
  639. beginchar(oct"100",11u#,asc_height#,0);
  640. adjust_fit(0,0); pickup fine.nib;
  641. pos1(cap_stem,75); pos2(cap_stem,90); pos3(cap_stem,90); pos4(cap_stem,75);
  642. lft x1l=hround u-eps; x2=2.5u=w-x3; rt x4r=hround(w-u)+eps;
  643. top y1r=h; bot y4l=0; z2=whatever[z1l,z4r]; z3=whatever[z1l,z4r];
  644. filldraw z1r{4(x1l-x1r),y1l-y1r}...{down}z1l...z2l
  645.  ---z3l...{down}z4l{4(x4r-x4l),y4r-y4l}...{up}z4r...z3r
  646.  ---z2r...{up}cycle; % long diagonal
  647. pos5(cap_stem,75); pos6(cap_stem,90); pos7(cap_stem,75);
  648. lft x5l=hround(w-4u)-eps; x6=.5[x5,x7]; x7=x4;
  649. y5=y1; bot y7l=x_height-o; z6=whatever[z5l,z7r];
  650. filldraw z5r{4(x5l-x5r),y5l-y5r}...{down}z5l
  651.  ...z6l{z7r-z5l}...{down}z7l{4(x7r-x7l),y7r-y7l}...{up}z7r
  652.  ...z6r{z5l-z7l}...{up}cycle; % short diagonal
  653. pos8(cap_hair,0); pos9(cap_hair,0); z8=z6; x9=x8-.75u; z9=whatever[z2,z3];
  654. filldraw stroke z8e{down}..{down}z9e;  % right stem
  655. pos10(cap_hair,-30); pos11(stem,0);
  656. pos12(cap_curve,0); pos13(cap_curve,0); pos14(vair,90);
  657. lft x11l=hround 1.5u; x10=x12=.4[x11,.5w]; z10=whatever[z2,z3];
  658. lft x13l=hround u; z13l=z14l; y11=.5y10; y12=.2[y14r,y11]; bot y13=0;
  659. filldraw stroke z10e{2(x11-x10),y11-y10}
  660.  ...z11e{down}..{down}z12e; % left stem
  661. filldraw z12r{down}...z13r---z13l--z14r{right}...{up}z12l--cycle; % flourish
  662. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  663.  
  664. cmchar "Multiset union sign";
  665. beginchar(oct"135",12u#,.8asc_height#,0); autorounded;
  666. adjust_fit(if monospace:-.5u#,-.5u# else: 0,0 fi); pickup rule.nib;
  667. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  668. y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
  669. draw z1---z2...z3...z4---z5;  % stems and cup
  670. y8=y9=.47[y1,y3]; x8=w-x9=x1+2rule_thickness+eps;
  671. x6=x7=x3; .5[y6,y7]=y8; y7-y6=x9-x8;
  672. draw z8--z9; draw z6--z7;  % enclosed plus sign
  673. labels(1,2,3,4,5,6,7,8,9); endchar;
  674.  
  675. cmchar "Left turnstile";
  676. beginchar(oct"140",11u#,asc_height#,0);
  677. adjust_fit(0,0); pickup rule.nib;
  678. .5[y1,y2]=y3=y4; x1=x2=x3;
  679. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  680. draw z1--z2;  % stem
  681. draw z3--z4;  % bar
  682. labels(1,2,3,4); endchar;
  683.  
  684. cmchar "Right turnstile";
  685. beginchar(oct"141",11u#,asc_height#,0);
  686. adjust_fit(0,0); pickup rule.nib;
  687. .5[y1,y2]=y3=y4; x1=x2=x4;
  688. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  689. draw z1--z2;  % stem
  690. draw z3--z4;  % bar
  691. labels(1,2,3,4); endchar;
  692.  
  693. cmchar "Left floor bracket";
  694. beginchar(oct"142",8u#,body_height#,paren_depth#);
  695. adjust_fit(0,0); pickup rule.nib;
  696. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  697. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  698. draw z1--z2--z3;  % stem and bar
  699. labels(1,2,3); endchar;
  700.  
  701. cmchar "Right floor bracket";
  702. beginchar(oct"143",8u#,body_height#,paren_depth#);
  703. adjust_fit(0,0); pickup rule.nib;
  704. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  705. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  706. draw z1--z2--z3;  % stem and bar
  707. labels(1,2,3); endchar;
  708.  
  709. cmchar "Left ceiling bracket";
  710. beginchar(oct"144",8u#,body_height#,paren_depth#);
  711. adjust_fit(0,0); pickup rule.nib;
  712. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  713. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  714. draw z3--z1--z2;  % stem and bar
  715. labels(1,2,3); endchar;
  716.  
  717. cmchar "Right ceiling bracket";
  718. beginchar(oct"145",8u#,body_height#,paren_depth#);
  719. adjust_fit(0,0); pickup rule.nib;
  720. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  721. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  722. draw z3--z1--z2;  % stem and bar
  723. labels(1,2,3); endchar;
  724.  
  725. cmchar "Left angle bracket";
  726. beginchar(oct"150",7u#,body_height#,paren_depth#);
  727. adjust_fit(0,0); pickup rule.nib;
  728. rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
  729. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  730. draw z1--z2--z3;  % diagonals
  731. labels(1,2,3); endchar;
  732.  
  733. cmchar "Right angle bracket";
  734. beginchar(oct"151",7u#,body_height#,paren_depth#);
  735. adjust_fit(0,0); pickup rule.nib;
  736. rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
  737. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  738. draw z1--z2--z3;  % diagonals
  739. labels(1,2,3); endchar;
  740.  
  741. cmchar "Double vertical line (norm or cardinality)";
  742. beginchar(oct"153",9u#,body_height#,paren_depth#);
  743. adjust_fit(0,0); pickup rule.nib;
  744. x1=x2; top y1=h; .5[y1,y2]=math_axis;
  745. x3=x4=w-x1; y3=y1; y4=y2;
  746. compute_spread(.45x_height#,.55x_height#); x3-x1=spread;
  747. draw z1--z2; draw z3--z4;  % stems
  748. labels(1,2,3,4); endchar;
  749.  
  750. cmchar "Up-and-down arrow";
  751. beginchar(oct"154",9u#,body_height#,paren_depth#);
  752. adjust_fit(0,0); pickup crisp.nib;
  753. pos1(rule_thickness,0); pos2(rule_thickness,0);
  754. pos3(rule_thickness,90); pos4(rule_thickness,90);
  755. lft x1l=hround(.5w-.5rule_thickness); y1=.5[-d,h];
  756. x0=x1=x2; bot y0=-d-o; x0-x3=x4-x0=4u+eps;
  757. y3=y4=y0+.36asc_height+eps;
  758. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  759. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  760. z9=.2[.5[z3,z4],z0];
  761. numeric t; path p; p=z4r{z9-z4}..z6r;
  762. t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
  763. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  764.  --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
  765.  --z3l{z9-z3}..z0 & cycle;  % lower arrowhead and stem
  766. pos11(rule_thickness,0); pos12(rule_thickness,0); z11=z1;
  767. pos13(rule_thickness,90); pos14(rule_thickness,90);
  768. x10=x11=x12; top y10=h+o; x10-x13=x14-x10=4u+eps;
  769. y13=y14=y10-.36asc_height-eps;
  770. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  771. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  772. z19=.2[.5[z13,z14],z10];
  773. numeric t; path p; p=z14l{z19-z14}..z16r;
  774. t=xpart(p intersectiontimes((x12r,-d)--(x12r,h))); y12=ypart point t of p;
  775. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  776.  --z12r---z11r..z11l---z12l--subpath (t,0) of\\(z13l{z19-z13}..z15r)
  777.  --z13r{z19-z13}..z10 & cycle;  % upper arrowhead and stem
  778. penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,19); endchar;
  779.  
  780. cmchar "Double up-and-down arrow";
  781. beginchar(oct"155",11u#,body_height#,paren_depth#);
  782. adjust_fit(0,0); pickup rule.nib;
  783. compute_spread(.45x_height#,.55x_height#);
  784. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  785. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  786. draw z1--z7; draw z2--z8;  % bars
  787. pickup crisp.nib; top y0=h+o; x0=good.x .5w;
  788. pos3(rule_thickness,90); pos4(rule_thickness,90);
  789. x2-x3=x4-x1=3u+eps; y3=y4=y0-.4asc_height-eps;
  790. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  791. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  792. z9=.381966[.5[z3,z4],z0];
  793. erase filldraw z0..{z3-z9}z3--(x3,h)
  794.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess at top
  795. numeric t; path p; p=z4l{z9-z4}..z6r;
  796. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  797. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  798.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  799.  --z3r{z9-z3}..z0 & cycle;  % top arrowhead
  800. bot y10=-d-o; x10=good.x .5w;
  801. pos13(rule_thickness,90); pos14(rule_thickness,90);
  802. x13=x3; x14=x4; y13=y14=y10+.4asc_height-eps;
  803. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  804. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  805. z19=.381966[.5[z13,z14],z10];
  806. erase filldraw z10..{z13-z19}z13--(x13,-d)
  807.  --(x14,-d)--z14{z19-z14}..z10 & cycle;  % erase excess at bottom
  808. numeric t; path p; p=z14r{z19-z14}..z16r;
  809. t=xpart(p intersectiontimes((x10,-d)--(x10,h)));
  810. filldraw z10..{z14-z19}z14l--subpath (0,t) of\\(z14r{z19-z14}..z16r)
  811.  --subpath (t,0) of\\(z13r{z19-z13}..z15r)
  812.  --z13l{z19-z13}..z10 & cycle;  % bottom arrowhead
  813. penlabels(0,1,2,3,4,5,6,7,8,9,13,14,15,16,19); endchar;
  814.  
  815. cmchar "Wreath product";
  816. beginchar(oct"157",5u#,asc_height#,asc_depth#);
  817. adjust_fit(if monospace: u#,u# else: 0,0 fi);
  818. pickup pencircle yscaled .7rule_thickness xscaled 1.4rule_thickness;
  819. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  820. lft x1=lft x3=hround u; x2=x4=w-x1;
  821. top y1=vround .75[math_axis,h];
  822. .5[y1,y4]=.5[y2,y3]=math_axis; y1-y2=1/4(y1-y4);
  823. draw z1{right}...z2{down}..{down}z3...{right}z4;  % stroke
  824. labels(1,2,3,4); endchar;
  825.  
  826. cmchar "Radical sign";
  827. beginchar(oct"160",15u#,rule_thickness#,
  828.  body_height#+paren_depth#-rule_thickness#);
  829. big_sqrt; endchar;
  830.  
  831. cmchar "Amalgamation symbol or coproduct symbol";
  832. beginchar(oct"161",13u#+width_adj#,cap_height#,0);
  833. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  834. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  835. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  836. pos3(cap_stem,0); pos4(cap_stem,0);
  837. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  838. top y1=top y3=h; bot y2=bot y4=0;
  839. filldraw stroke z1e--z2e; % left stem
  840. filldraw stroke z3e--z4e; % right stem
  841. penpos5(cap_bar,90); penpos6(cap_bar,90);
  842. x5=x1; x6=x3; y5=y6; y5l=0;
  843. fill stroke z5e--z6e;  % bar
  844. if serifs: numeric inner_jut;
  845.  if rt x1r+cap_jut+u+2<=lft x3l-cap_jut: inner_jut=cap_jut;
  846.  else: rt x1r+inner_jut+u+2=lft x3l-inner_jut; fi
  847.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  848.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,eps); % lower left serif
  849.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper right serif
  850.  nodish_serif(4,3,g,1/3,eps,h,1/3,cap_jut); fi  % lower right serif
  851. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  852.  
  853. cmchar "Nabla or backwards-difference operator";
  854. beginchar(oct"162",15u#,cap_height#,0);
  855. adjust_fit(0,0);
  856. numeric right_stem,alpha;
  857. right_stem=cap_hair if hefty: -3stem_corr fi;
  858. x1l=w-x4r=.75u; y1=y4=h;
  859. x2-x1=x4-x3; x3l=x2l+apex_corr; y2=y3=-apex_o-apex_oo;
  860. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  861. penpos1(alpha*cap_stem,0); penpos2(alpha*cap_stem,0);
  862. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  863. fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle;  % triangle
  864. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  865. y5=y6=h-cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
  866. if y0>cap_notch_cut: y0:=cap_notch_cut;
  867.  unfill z0+.5right{up}...{z4-z3}z6--z5{z2-z1}
  868.   ...{down}z0+.5left--cycle; % counter
  869. else: unfill z0--z5--z6--cycle; fi  % counter
  870. penlabels(0,1,2,3,4,5,6); endchar;
  871.  
  872. cmchar "Square set union sign (Scott lub)";
  873. beginchar(oct"164",12u#,.8asc_height#,0);
  874. adjust_fit(0,0); pickup rule.nib;
  875. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  876. y1=good.y h+o; bot y2=0; y4=y2; y5=y1;
  877. draw z1---z2---z4---z5;  % stems and bar
  878. labels(1,2,4,5); endchar;
  879.  
  880. cmchar "Square set intersection sign (Scott glb)";
  881. beginchar(oct"165",12u#,.8asc_height#,0);
  882. adjust_fit(0,0); pickup rule.nib;
  883. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  884. y2=good.y h+o; bot y1=0; y4=y2; y5=y1;
  885. draw z1---z2---z4---z5;  % stems and bar
  886. labels(1,2,4,5); endchar;
  887.  
  888. cmchar "Square subset or equal to sign";
  889. compute_spread(.45x_height#,.55x_height#);
  890. spread#':=spread#; spread':=spread; % the spread of `$=$'
  891. compute_spread(5/4x_height#,3/2x_height#);
  892. beginchar(oct"166",14u#,v_center(spread#'+spread#+rule_thickness#));
  893. adjust_fit(0,0); pickup rule.nib;
  894. lft x2=hround(1.5u+oo); x1=x4=hround(w-1.5u)+eps; x3=x2;
  895. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  896. draw z1--z2--z3--z4;  % bars and stem
  897. x8=x1; x9=x2-oo-eps; y8=y9; y4-y9=spread';
  898. draw z8--z9;  % lower bar
  899. labels(1,2,3,4,8,9); endchar;
  900.  
  901. cmchar "Square superset or equal to sign";
  902. compute_spread(.45x_height#,.55x_height#);
  903. spread#':=spread#; spread':=spread; % the spread of `$=$'
  904. compute_spread(5/4x_height#,3/2x_height#);
  905. beginchar(oct"167",14u#,v_center(spread#'+spread#+rule_thickness#));
  906. adjust_fit(0,0); pickup rule.nib;
  907. x1=x4=hround 1.5u-eps; rt x2=hround(w-1.5u-oo); x3=x2;
  908. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  909. draw z1--z2--z3--z4;  % bars and stem
  910. x8=x1; x9=x2+oo+eps; y8=y9; y4-y9=spread';
  911. draw z8--z9;  % lower bar
  912. labels(1,2,3,4,8,9); endchar;
  913.  
  914. cmchar "Section sign";
  915. beginchar(oct"170",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
  916. adjust_fit(0,0); pickup fine.nib;
  917. numeric sstem; sstem=hround .75[hair,stem];
  918. pos0(stem,0); pos1(hair,0); pos2(vair,90); pos3(sstem,180); pos4(vair,270);
  919. pos5'(sstem,0); pos5(sstem,180);
  920. pos6(vair,90); pos7(sstem,0); pos8(vair,-90); pos9(hair,-180); pos10(stem,-180);
  921. top y2r=h+oo; bot y8r=-d-oo; y2-y1=y9-y8=(y2-y8)/8;
  922. y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
  923. y2-y4=y4-y6=y6-y8;
  924. rt x1r=hround(w-1.5u); lft x3r=hround 1.25u;
  925. x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3; x9=w-x1;
  926. bulb(2,1,0); bulb(8,9,10);  % bulbs
  927. filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
  928.  ...z5e{down}...{left}z6e;  % upper stroke
  929. filldraw stroke z4e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
  930.  ...z7e{down}...{left}z8e;  % upper stroke
  931. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  932.  
  933. cmchar "Dagger mark";
  934. beginchar(oct"171",8u#,asc_height#,desc_depth#);
  935. adjust_fit(0,0); pickup fine.nib;
  936. pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
  937. pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
  938. x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); center_on(x1);
  939. x5-.5stem=hround u; x6=w-x5;
  940. y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
  941. y5+.5stem=floor(x_height+.5stem);
  942. filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e;  % stem
  943. filldraw circ_stroke z5e{right}..{right}z2'e;  % left bulb
  944. filldraw circ_stroke z6e{left}..{left}z2'e;  % right bulb
  945. penlabels(1,2,3,4,5,6); endchar;
  946.  
  947. cmchar "Double dagger mark";
  948. beginchar(oct"172",8u#,asc_height#,desc_depth#);
  949. adjust_fit(0,0); pickup fine.nib;
  950. pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
  951. pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
  952. x1=x2=x3; x1-.5stem=hround(.5w-.5stem); center_on(x1);
  953. x4-.5stem=hround u; x5=w-x4;
  954. y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
  955. filldraw circ_stroke z1e{down}..{down}z2e;  % top stem
  956. filldraw circ_stroke z3e{up}..{up}z2e;    % upper middle stem
  957. filldraw circ_stroke z4e{right}..{right}z2'e;  % top left bulb
  958. filldraw circ_stroke z5e{left}..{left}z2'e;  % top right bulb
  959. pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
  960. pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
  961. x6=x7=x8=x1; x9=x4; x0=x5;
  962. y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
  963. filldraw circ_stroke z6e{down}..{down}z7e;  % lower middle stem
  964. filldraw circ_stroke z8e{up}..{up}z7e;    % bottom stem
  965. filldraw circ_stroke z9e{right}..{right}z7'e;  % bottom left bulb
  966. filldraw circ_stroke z0e{left}..{left}z7'e;  % bottom right bulb
  967. penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
  968.  
  969. cmchar "Paragraph mark";
  970. beginchar(oct"173",11u#,asc_height#,desc_depth#);
  971. adjust_fit(0,0); pickup rule.nib; autorounded;
  972. top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
  973. y8=y6; y3=y5=good.y .5[y1,y6];
  974. x7-x4=ceiling(rule_thickness+1.25u);
  975. lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
  976. x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
  977. filldraw z4..z1{left}...z2{down}...{right}z5--cycle;  % filled bowl
  978. draw z9--z4--z6;  % left stem and upper serif
  979. draw z7--z8;  % right stem
  980. labels(1,2,3,4,5,6,7,8,9); endchar;
  981.  
  982. cmchar "Club suit";
  983. beginchar(oct"174",14u#,asc_height#,2/3desc_depth#);
  984. adjust_fit(0,0); pickup rule.nib; autorounded;
  985. x1=x4=x30=x33=good.x .5w; center_on(x1);
  986. x2=good.x(x1-.5u)-eps; lft x1-rt x10=hround .5pt; lft x12=hround .5u;
  987. x11=.6[x12,x10]; x13=.5[x12,x10]=x5; x32-x31=x1-.5u-x12;
  988. x2+x3=x5+x6=x10+x20=x11+x21=x12+x22=x13+x23=x31+x32=2x1;
  989. top y30=h+o+oo; bot y11=bot y21=-o; top y13=top y23=vround .53h;
  990. y30-y33=y13-y11; y31=y32=y4=.5[y30,y33]; y12=y22=.5[y11,y13];
  991. y1=y10=y20=good.y .1h; bot y5=bot y6=y1+.75; bot y2=bot y3=-d;
  992. filldraw z30{left}...z31{down}...z33{right}...z32{up}...cycle;  % top bowl
  993. filldraw z13{left}...z12{down}...z11{right}...z10{up}...cycle;  % left bowl
  994. filldraw z23{left}...z20{down}...z21{right}...z22{up}...cycle;  % right bowl
  995. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  996.  ...{up}cycle;  % stem
  997. filldraw z4--z5--z6--cycle;  % filling
  998. labels(1,2,3,4,5,6,10,11,12,13,20,21,22,23,30,31,32,33); endchar;
  999.  
  1000. cmchar "Diamond suit";
  1001. beginchar(oct"175",14u#,asc_height#,2/3desc_depth#);
  1002. adjust_fit(0,0); pickup rule.nib; autorounded;
  1003. x1=x4=good.x .5w; center_on(x1);
  1004. lft x2=hround u; x3=w-x2;
  1005. top y1=h+o+oo; bot y4=-d-o-oo; y2=y3=.5[y1,y4];
  1006. draw z1{x3-x1,1.5(y3-y1)}...z3{1.5(x3-x1),y3-y1};  % upper right diagonal
  1007. draw z1{x2-x1,1.5(y2-y1)}...z2{1.5(x2-x1),y2-y1};  % upper left diagonal
  1008. draw z4{x2-x4,1.5(y2-y4)}...z2{1.5(x2-x4),y2-y4};  % lower left diagonal
  1009. draw z4{x3-x4,1.5(y3-y4)}...z3{1.5(x3-x4),y3-y4};  % lower right diagonal
  1010. labels(1,2,3,4); endchar;
  1011.  
  1012. cmchar "Heart suit";
  1013. beginchar(oct"176",14u#,asc_height#,2/3desc_depth#);
  1014. adjust_fit(0,0); pickup rule.nib; autorounded;
  1015. x1=x5=good.x .5w; center_on(x1);
  1016. lft x7=hround u; x8=4u; x2+x8=x3+x7=x4+x6=w;
  1017. y1=good.y .77h; top y2=h+o; y3=.7h; y4=.2h; bot y5=-o-oo;
  1018. y2=y8; y3=y7; y4=y6; z4=whatever[z3,z5];
  1019. x0=x9=w; y0=1.5h; y9=.6h;
  1020. draw z1{x2-x1,8(y2-y1)}...z2{right}....z3{down}...{z4-z9}z4
  1021.  ...{z5-z0}z5;  % right half bowl
  1022. draw z1{x8-x1,8(y8-y1)}...z8{left}....z7{down}...{(z4-z9)xscaled-1}z6
  1023.  ...{(z5-z0)xscaled-1}z5;  % left half bowl
  1024. labels(0,1,2,3,4,5,6,7,8,9); endchar;
  1025.  
  1026. cmchar "Spade suit";
  1027. beginchar(oct"177",14u#,asc_height#,2/3desc_depth#);
  1028. adjust_fit(0,0); pickup rule.nib; autorounded;
  1029. x1=x10=good.x .5w; center_on(x1);
  1030. x2=good.x(x1-.5u)-eps; lft x1-rt x6=hround .5pt; x5=x6;
  1031. x7=.5[x8,x6]; lft x8=hround u;
  1032. x2+x3=x5+x15=x6+x14=x7+x13=x8+x12=x9+x11=2x10;
  1033. top y10=h+o+oo; y9=y11=.7h; y8=y12=.3h;
  1034. y1=y6=y14=good.y .1h; bot y5=bot y15=y1+.75;
  1035. bot y7=bot y13=-o; bot y2=bot y3=-d; z9=whatever[z8,z10];
  1036. filldraw z10{-w,-3h}...z9{-w,-h}...z8{down}...z7{right}...z6---z5
  1037.  --z15---z14...{right}z13...{up}z12...{-w,h}z11
  1038.  ...{-w,3h}cycle;  % filled bowl
  1039. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  1040.  ...{up}cycle;  % stem
  1041. labels(1,2,3,5,6,10,11,12,13,14,15); endchar;
  1042.